2 files changed, 81 insertions, 0 deletions
diff --git a/assets/final/shaders/render/scene_query_bvh.wgsl b/assets/final/shaders/render/scene_query_bvh.wgsl
new file mode 100644
index 0000000..c7dfdf4
--- /dev/null
+++ b/assets/final/shaders/render/scene_query_bvh.wgsl
@@ -0,0 +1,55 @@
+#include "math/sdf_shapes"
+#include "math/sdf_utils"
+
+struct BVHNode {
+    min: vec3<f32>,
+    left_idx: i32,
+    max: vec3<f32>,
+    obj_idx_or_right: i32,
+};
+
+@group(0) @binding(2) var<storage, read> bvh_nodes: array<BVHNode>;
+
+fn get_dist(p: vec3<f32>, obj_type: f32) -> f32 {
+    if (obj_type == 1.0) { return length(p) - 1.0; } // Unit Sphere
+    if (obj_type == 2.0) { return sdBox(p, vec3<f32>(1.0)); } // Unit Box
+    if (obj_type == 3.0) { return sdTorus(p, vec2<f32>(1.0, 0.4)); } // Unit Torus
+    if (obj_type == 4.0) { return sdPlane(p, vec3<f32>(0.0, 1.0, 0.0), 0.0); }
+    return 100.0;
+}
+
+fn map_scene(p: vec3<f32>, skip_idx: u32) -> f32 {
+    var d = 1000.0;
+    var stack: array<i32, 32>;
+    var stack_ptr = 0;
+    
+    if (arrayLength(&bvh_nodes) > 0u) {
+        stack[stack_ptr] = 0;
+        stack_ptr++;
+    }
+
+    while (stack_ptr > 0) {
+        stack_ptr--;
+        let node_idx = stack[stack_ptr];
+        let node = bvh_nodes[node_idx];
+
+        if (aabb_sdf(p, node.min, node.max) < d) {
+            if (node.left_idx < 0) { // Leaf
+                let obj_idx = u32(node.obj_idx_or_right);
+                if (obj_idx == skip_idx) { continue; }
+                let obj = object_data.objects[obj_idx];
+                let q = (obj.inv_model * vec4<f32>(p, 1.0)).xyz;
+                let s = min(length(obj.model[0].xyz), min(length(obj.model[1].xyz), length(obj.model[2].xyz)));
+                d = min(d, get_dist(q, obj.params.x) * s);
+            } else { // Internal
+                if (stack_ptr < 31) {
+                    stack[stack_ptr] = node.left_idx;
+                    stack_ptr++;
+                    stack[stack_ptr] = node.obj_idx_or_right;
+                    stack_ptr++;
+                }
+            }
+        }
+    }
+    return d;
+}
diff --git a/assets/final/shaders/render/scene_query_linear.wgsl b/assets/final/shaders/render/scene_query_linear.wgsl
new file mode 100644
index 0000000..7bcd96f
--- /dev/null
+++ b/assets/final/shaders/render/scene_query_linear.wgsl
@@ -0,0 +1,26 @@
+#include "math/sdf_shapes"
+
+fn get_dist(p: vec3<f32>, obj_type: f32) -> f32 {
+    if (obj_type == 1.0) { return length(p) - 1.0; } // Unit Sphere
+    if (obj_type == 2.0) { return sdBox(p, vec3<f32>(1.0)); } // Unit Box
+    if (obj_type == 3.0) { return sdTorus(p, vec2<f32>(1.0, 0.4)); } // Unit Torus
+    if (obj_type == 4.0) { return sdPlane(p, vec3<f32>(0.0, 1.0, 0.0), 0.0); }
+    return 100.0;
+}
+
+fn map_scene(p: vec3<f32>, skip_idx: u32) -> f32 {
+    var d = 1000.0;
+    let count = u32(globals.params.x);
+    
+    for (var i = 0u; i < count; i = i + 1u) {
+        if (i == skip_idx) { continue; }
+        let obj = object_data.objects[i];
+        let obj_type = obj.params.x;
+        if (obj_type <= 0.0) { continue; } 
+
+        let q = (obj.inv_model * vec4<f32>(p, 1.0)).xyz;
+        let s = min(length(obj.model[0].xyz), min(length(obj.model[1].xyz), length(obj.model[2].xyz)));
+        d = min(d, get_dist(q, obj_type) * s);
+    }
+    return d;
+}