struct Particle {
    pos: vec4<f32>,
    vel: vec4<f32>,
    rot: vec4<f32>,
    color: vec4<f32>,
};

struct Uniforms {
    intensity: f32,
    aspect_ratio: f32,
    time: f32,
    beat: f32,
};

@group(0) @binding(0) var<storage, read_write> particles: array<Particle>;
@group(0) @binding(1) var<uniform> uniforms: Uniforms;

fn hash(p: f32) -> f32 {
    return fract(sin(p) * 43758.5453);
}

@compute @workgroup_size(64)
fn main(@builtin(global_invocation_id) id: vec3<u32>) {
    let i = id.x;
    if (i >= arrayLength(&particles)) {
        return;
    }
    var p = particles[i];
    if (p.pos.w <= 0.0) {
        let r = hash(f32(i) + uniforms.time);
        let angle = r * 6.28318;
        p.pos = vec4<f32>(0.0, 0.0, 0.0, 1.0);
        p.vel = vec4<f32>(cos(angle), sin(angle), 0.0, 0.0) * (0.5 + hash(r) * 0.5) * (1.0 + uniforms.intensity * 2.0);
        p.color = vec4<f32>(hash(r + 0.1), hash(r + 0.2), 1.0, 1.0);
    }
    let new_pos = p.pos.xyz + p.vel.xyz * 0.016;
    p.pos = vec4<f32>(new_pos, p.pos.w - 0.01 * (1.0 + uniforms.beat));
    p.vel.y = p.vel.y - 0.01;
    particles[i] = p;
}